Tags:    delphi


Nu er det meget lettere at styre firkanten! Der er stor forskel på om du først rotere og dernæst flytter en geometri eller omvendt. Prøv eventuelt at bytte om på de to kald og se selv forskellen. Bliver en geometri først flyttet for dernæst at blive roteret, vil den rotere omkring sig selv. Men bliver den derimod først roteret for dernæst at blive flyttet, vil den rotere rundt om viewporten!

Når vi laver et spil har vi ofte brug for en slags kamera. Det findes bare ikke en egentlig kamera i OpenGL! Det eneste du kan gøre er at flytte og rotere rundt på geometrien. Men som jeg lige nævnte, så er der stor forskel på om du først rotere og dernæst flytter en geometri. Dette kan vi udnytte. Så i stedet for at vi bevæger os rundt om geometrien, lader vi geometrien flytte rundt om os! Da vi naturligvis ikke kan se andet end dét geometri vi har tegnet, vil man ikke kunne ane forskel i lige vel. Men hvordan kan vi så komme til at bevæge os rundt i en 3D verden, ligesom eksempelvis Doom og Quake? Hemmeligheden er Sinus og Cosinus. Det unikke for netop de to matematiske begreber, er, at når den ene er 0 er den anden 1, hvis vel og mærket, vi bruger samme værdier for dem begge. Da vi ønsker at bevæge os rundt, som om vi faktisk går, inde i en 3D verden, behøver vi kun at koncentrere os om X of Z akserne for vores Translation. Da vi yderligere kun kan dreje til højre og venstre, behøver vi derfor kun at koncentrere os om Y aksen i vores Rotation. Lad os derfor prøve at lave en stor firkant som gulv, som vi kan bevæge os hen over. Før du kompiler, skal du lige huske at tilføje "Math" under uses, da vi benytter DegToRad() (Degrees to Radians):

var
  Translation, Rotation : TVector;
procedure TForm1.FormPaint(Sender: TObject);
begin
  glClearColor(0,0,0,0);
  glClear(gl_Color_Buffer_Bit);

  glPushMatrix;
  
  //Rotation og Translation er blevet byttet om fra tidligere eksempel!

  with Rotation do
  begin
    glRotatef(X,1,0,0);
    glRotatef(Y,0,1,0);
    glRotatef(Z,0,0,1);
  end;

  with Translation do
  glTranslatef(X,Y,Z);

  //Tegner mit gulv som en stor firkant
  glBegin(gl_Quads);

  glColor3ub(255,0,0);
  glVertex3f(-50, -3, -50);

  glColor3ub(0,255,0);
  glVertex3f(-50, -3, +50);

  glColor3ub(0,0,255);
  glVertex3f(+50, -3, +50);

  glColor3ub(255,255,0);
  glVertex3f(+50 ,-3 ,-50);

  glEnd;

  glPopMatrix;

  SwapBuffers(Context.DeviceContext);
end;

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  case Key of

    //Drej til venstre
    VK_Left: Rotation.Y := Rotation.Y-1;

    //Drej til højre
    VK_Right: Rotation.Y := Rotation.Y+1;

    //Gå fremad 
    VK_Up: begin
             Translation.X := Translation.X-Sin(DegToRad(Rotation.Y));
             Translation.Z := Translation.Z+Cos(DegToRad(Rotation.Y));
           end;

    //Gå tilbage
    VK_Down: begin
               Translation.X := Translation.X+Sin(DegToRad(Rotation.Y));
               Translation.Z := Translation.Z-Cos(DegToRad(Rotation.Y));
             end;
    end; //Case
  FormPaint(nil);
end;

For at kigge op og ned kan vi gøre det meget enkelt bare ved at rotere rundt om X aksen. Jeg har valgt at bruge Insert og Delete tasterne til dette formål:

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  case Key of
    VK_Left: Rotation.Y := Rotation.Y-1;
    VK_Right: Rotation.Y := Rotation.Y+1;
    VK_Up: begin
             Translation.X := Translation.X-Sin(DegToRad(Rotation.Y));
             Translation.Z := Translation.Z+Cos(DegToRad(Rotation.Y));
           end;
    VK_Down: begin
               Translation.X := Translation.X+Sin(DegToRad(Rotation.Y));
               Translation.Z := Translation.Z-Cos(DegToRad(Rotation.Y));
             end;

    //Kig ned
    VK_Insert: Rotation.X := Rotation.X+1;

    //Kig op
    VK_Delete: Rotation.X := Rotation.X-1;
    end; //Case
  FormPaint(nil);
end;

Hvis du kompiler, vil du se at det faktisk føles som om du går rundt på det nye gulv! Lad os forestille os, at vi også gerne ville kunne hoppe ligesom i Quake. Der er bare dét problem, at når man hopper, sker der en hel automatisk bevægelse. Indtil nu har vi ladet OpenGL rendere nye frames for, hver gang vi tastede en tast. For at løses dette problem, bliver vi nødt til at få et eller andet til autoimatisk at rendere vores 3D verden. Til dette formål er vores applikations OnIdle indelysende. Så lad os lave en Idle procedure, der tage sig af den automatiske rendering. Skriv dette under din TForm1's Private Declarations. Hvis du bruger en højere version end Delphi 4, må du se i din hjælpfil, hvordan man laver en Idle procedure til din Delphi kompiler:

procedure Idle(Sender : TObject; var Done : Boolean);

og implementer så selve proceduren med følgende kode nederst i din unit:

procedure TForm1.Idle(Sender : TObject; var Done : Boolean);
begin
  Done := False;

  FormPaint(nil);
end;

Tilføj følgende kode i din FormCreate() procedure og fjern din FormPaint(nil) i din FormKeyDown procedure:

procedure TForm1.FormCreate(Sender: TObject);
begin
  Context := SetupContext(Form1);

  //Assigner vore Idle procedure til vore applikation
  Application.OnIdle := Idle;
end;

Prøv at kompile og se om ikke din Idle procedure opdatér din FormPaint() procedure korrekt. Hvis det virker som før, virker det korrekt! Det vil være meget brugbart i fremtiden at kunne se, hvor mange gange i sekundet OpenGL rendere vores kode. Dette kan gøres meget hurtig ved at trække en TTimer komponent ned på vores form. Tilføj to globale varianter: FPS og I som Integer, og skriv følgende i din Idle procedure:

var
  FPS, I : Integer;
procedure TForm1.Idle(Sender : TObject; var Done : Boolean);
begin
  Done := False;

  FormPaint(nil);

  //Viser FPS i vores forms caption
  Caption := IntToStr(FPS);
  Inc(I);
end;

I din TTimer's OnTimer property skal du skrive følgende:

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  FPS := I;
  I := 0;
end;

Kompile nu koden. Du vil forhåbentligt kunne se, at et tal dukker op i din forms caption. Dette tal viser hvor mange gange i sekundet (FPS - Frames Per Second) vores kode vil blive renderet af OpenGL - på min computer er det omkring 60 (Da min skærms Refresh Rate er sat til 60). Det er ikke helt præcist, da TTimer'en ikke helt præcists timer for hvert sekund, men det er præcists nok for os. Da vi nu hele tiden får vores kode renderet har vi nu mulighed for at lave vores ønskede hoppe bevægelse. Da vi ikke kan lave selve hoppe "animationen" i vores OnKeyDown procedure alene, har jeg valgt at skrive den i Idle proceduren. Tilføj derfor en ny variant: Jump som en Boolean. Når Jump er true bliver hoppe bevægelsen aktiveret i Idle proceduren.

var
  FPS, I : Integer;
  Jump : Boolean;
procedure TForm1.Idle(Sender : TObject; var Done : Boolean);
begin
  Done := False;
  
  //Hoppe beægelse 
  if Jump then
  begin
    //Hopper "op" i luften...
    if Translation.Y > -1 then
    Translation.Y := Translation.Y-0.1
    else
      Jump := False;
  end
  else
    //...og falder ned på gulvet igen
    if Translation.Y < 0 then
    Translation.Y := Translation.Y+0.1;

  FormPaint(nil);

  Caption := IntToStr(FPS);
  Inc(I);
end;

Som du kan se bliver gulvet presset -1 unit ned langs Y aksen (med et interval på -0.1 unit), hvilket får det til at se ud som om, at vi hopper op ad!. Jeg har valgt at bruge min Space tast til at aktivere hoppe bevægelsen med, skriv derfor følgende kode i OnKeyDown proceduren:

procedure TForm1.FormKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  case Key of

    VK_Left: Rotation.Y := Rotation.Y-1;
    VK_Right: Rotation.Y := Rotation.Y+1;
    VK_Up: begin
             Translation.X := Translation.X-Sin(DegToRad(Rotation.Y));
             Translation.Z := Translation.Z+Cos(DegToRad(Rotation.Y));
           end;
    VK_Down: begin
               Translation.X := Translation.X+Sin(DegToRad(Rotation.Y));
               Translation.Z := Translation.Z-Cos(DegToRad(Rotation.Y));
             end;
    VK_Insert: Rotation.X := Rotation.X+1;
    VK_Delete: Rotation.X := Rotation.X-1;

    //Aktivere vores hoppe bevægelse i Idle proceduren 
    VK_Space: Jump := True;
    end; //Case
end;

Hvad synes du om denne artikel? Giv din mening til kende ved at stemme via pilene til venstre og/eller lægge en kommentar herunder.

Del også gerne artiklen med dine Facebook venner:  

Karma barometer (30 dage)

IT jobs | Kontakt | Om Udvikleren.dk | Om karma | IT nyheds arkiv | Annoncering

X