Tags:    delphi
-= START =-

Da vi nu gerne skulle havde en idé om, hvordan OpenGL fungere i forhold til vores applikation og Windows, er det på tide at se noget kode. Først vil vi se på, hvordan vi kan lave en context til en, hvilken som helst visuel delphi komponent. Vi får både brug for en renderings context og en device context, der begge er af typen THandle. Så hvorfor ikke definere en record der består af disse:

type
  TContext = record
    RenderContext, DeviceContext : THandle;
  end;

Nu ville det være smart at lave en funtion der kan returnere en sådan record ud til os, hvis bare vi fortæller den, hvilken Delphi komponent vi vil havde lavet vores context for:

function SetupContext(Sender : TObject) : TContext;
var
  PFD: PixelFormatDescriptor;
  I : Integer;
begin
  with TWinControl(Sender) do
  Result.DeviceContext := GetDC(Handle);

  ZeroMemory(@PFD,SizeOf(PFD));

  with PFD do
  begin
    nSize := Sizeof(PixelFormatDescriptor);
    nVersion := 1;
    dwFlags := pfd_Support_OpenGL or pfd_Draw_to_Window or pfd_DoubleBuffer;
    iPixelType := pfd_Type_RGBA;
    cColorBits := 24;
    cDepthBits := 32;
    iLayerType := pfd_Main_Plane;
  end;

  I := ChoosePixelFormat(Result.DeviceContext,@PFD);

  if I = 0 then
  Exit;

  if not SetPixelFormat(Result.DeviceContext, I, @PFD) then
  Exit;

  Result.RenderContext := wglCreateContext(Result.DeviceContext);

  if Result.RenderContext = 0 then
  Exit;

  if not wglMakeCurrent(Result.DeviceContext, Result.RenderContext) then
  Exit;
end;

PixelFormatDesciptor er en Windows type og indeholder beskrivelsen for en pixel type. nSize er såmænd bare storrelsen på sin egen type. Desuden fortæller vi at den skal uderstøtte OpenGL og tegne til et vindue (Visuel komponent) og at OpenGL's DoubleBuffer skal være tilgængeligt ved dwFlags, og at pixel typen er en RGBA (Red, Green, Blue, Alpha). Til sidst bliver vores nye context aktiveret. Da vi kun skal lave vores context én gang, vil det vaere oplagt at skrive det i vores forms OnCreate property:

var
  Context : TContext;
procedure TForm1.FormCreate(Sender: TObject);
begin
  //Referere til vores funktion, der vil returnere en context til vores form
  Context := SetupContext(Form1);
end;

Lad os nu se om det overhovedet virker, ved at farve OpenGL's Color buffer og bytte den med Windows (GDI) buffer. Vi skriver derfor følgende i vores forms OnPaint property:

procedure TForm1.FormPaint(Sender: TObject);
begin
  //Definere farven der skal overskrive Color bufferen
  glClearColor(0,0,0,0);

  //Overskriver Color bufferen
  glClear(gl_Color_Buffer_Bit);

  //Bytter OpenGL's Color buffer med Windows (GDI'en)
  SwapBuffers(Context.DeviceContext);
end;

Prøver vi at kompile, skulle vi gerne se at vores form er blevet helt sort. glClear() fortæller OpenGL hvilken farve Color bufferen skal farves med når den bliver overskrevet (0,0,0,0) - hvilket er sort! glClear() fortæller hvilke buffers der skal overskrives - i vores tilfælde er det kun gl_Color_Buffer. Grunden til at vi overskriver en buffer er selvfølgelig for at forberede en ny rendering. Husk på at spil bliver renderet som om det var en film. Der bliver hele tiden tegnet nye billeder (også kaldet for Frames) for hvert sekund. Ofte har vi en frame rate - FPS (Frames Per Second) på ca. 60 + 75. Afhaengig af dit hvad dit system tillader. Prøv nu eventuelt at tage en TPanel og lav en context til den i stedet for din Form, eller en hvilket som helst anden visuel Delphi komponent (Det kan være du bliver nødt til at maksimere din Form, når din applikation er eksekveret for at se et resultatet). I de kommende eksempler bliver der antaget at der er blevet lavet en context til din Form!
OpenGL har forskellige måder at definere RGB(A) farver på. I funktionen glClearColor() bruger vi float (Singles) til at definere farven med, hvor imod Windows altid definere RGB farver som bytes. Her er en lille sammenligning mellem disse to farve defineringer:

RGB( Rød  Grøn   Blå)   OPENGL      ( Rød  , Grøn , Blå  , Alpha) FARVE
-----------------------------------------------------------------------------
RGB( 255 , 255 , 255 )  glClearColor( 1    , 1    , 1    , 0 )    Hvid 
RGB( 128 , 128 , 128 )  glClearColor( 0.5  , 0.5  , 0.5  , 0 )    Grå 
RGB( 0   , 0   , 0   )  glClearColor( 0    , 0    , 0    , 0 )    Sort 
RGB( 255 , 0   , 0   )  glClearColor( 1    , 0    , 0    , 0 )    Rød 
RGB( 0   , 255 , 0   )  glClearColor( 0    , 1    , 0    , 0 )    Grøn 
RGB( 0   , 0   , 255 )  glClearColor( 0    , 0    , 1.0  , 0 )    Blå 
RGB( 255 , 255 , 0   )  glClearColor( 1    , 1    , 0    , 0 )    Gul 
RGB( 255 , 64  , 0   )  glClearColor( 1    , 0.63 , 0    , 0 )    Brun 
RGB( 0   , 255 , 255 )  glClearColor( 0    , 1    , 1    , 0 )    Turkis 
RGB( 255 , 0   , 255 )  glClearColor( 1    , 0    , 1    , 0 )    Lilla 

Da vi nu ved, hvordan vi skal arbejde med OpenGL med Delphi, vil vi prøve at rendere noget geometri. Men før vi koder et eksempel er det meget vigtigt at forstå, hvordan 3D modeller er bygget op. Da det handler om at simplificér alt i 3D, arbejder vi derfor også med meget simple primitiver, så som prikker, streger og trekanter. Har vi to trekanter som en primitiv kaldes det en Quad (firkant) og har vi flere end to trekanter i en primitiv, kalder vi den for en polygon. Men vigtigst er det at vide at alt stort set er bygget op af trekanter også begreber som NURBS! Da 3D er vektor baseret grafik, vil en figur meget logisk være opbygget af punkter også kaldet for vertexer. Hver af disse punkter indeholder 3 koordinater (X,Y,Z) som er af typen float (Singles). Hvis vi vil tegne en enkelt trekant kan vi derfor gøre det således:

  glBegin(gl_Triangles);
  glVertex3f(0 ,+1,0);
  glVertex3f(+1,-1,0);
  glVertex3f(-1,-1,0);
  glEnd;

Som du kan se, har vi defineret en primitiv via glBegin() og afslutter med glEnd, og hver vertex med glVertex3f(). Hvis vi sætter det sammen med koden i vores FormPaint procedure, vil det være mest fornuftig at skrive koden efter vi overskriver Color bufferen og før vi bytter Color bufferen:

procedure TForm1.FormPaint(Sender: TObject);
begin
  glClearColor(0,0,0,0);
  glClear(gl_Color_Buffer_Bit);

  //Tegner en trekant med gl_Triangles
  glBegin(gl_Triangles);
  glVertex3f(0,    +0.5, 0);
  glVertex3f(+0.5, -0.5, 0);
  glVertex3f(-0.5, -0.5, 0);
  glEnd;

  SwapBuffers(Context.DeviceContext);
end;

Hvad synes du om denne artikel? Giv din mening til kende ved at stemme via pilene til venstre og/eller lægge en kommentar herunder.

Del også gerne artiklen med dine Facebook venner:  

Karma barometer (30 dage)

IT jobs | Kontakt | Om Udvikleren.dk | Om karma | IT nyheds arkiv | Annoncering

X