Stopur

her er så et hurtigt lavet vb6 projekt...
www.ctcsite.dk/stopur.zip

koden ser sådan ud:

Dim sekunder As Integer


Private Sub Command1_Click()

sekunder = 0
Open "sekunder.txt" For Output As #2
Print #2, sekunder
Close #2
Label1.Caption = sekunder

End Sub

Private Sub Command1_KeyDown(KeyCode As Integer, Shift As Integer)
If KeyCode = vbKeyF12 Then
Timer1.Interval = 1000
ElseIf KeyCode = vbKeyF11 Then
Timer1.Interval = 0
End If
End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
If KeyCode = vbKeyF12 Then
Timer1.Interval = 1000
ElseIf KeyCode = vbKeyF11 Then
Timer1.Interval = 0
End If
End Sub

Private Sub Form_Load()
On Error GoTo fejl

Open "sekunder.txt" For Input As #1
Line Input #1, temp
Close #1
sekunder = temp
Label1.Caption = sekunder

fejl:
Exit Sub

End Sub

Private Sub Timer1_Timer()

sekunder = sekunder + 1
Open "sekunder.txt" For Output As #2
Print #2, sekunder
Close #2
Label1.Caption = sekunder

End Sub

de eneste controls er en knap, en label og en timer

[Redigeret d. 09/10-05 21:21:35 af Christian]

Her er det brugt i en kode, som er forklaret så du kan lære syntaxen, ikke algoritmen! Alt hvad det kræver er at du har en 'Label', hvis property 'Name' er sat til "lblTime".

- Du stopper og nulstiller stopuret på F9
- Du starter stopuret på F11
- Du stopper stopuret på F12

Her er også lidt guf til Cristian så han kan lære ikke at bruge de grimme "On Error" koder

'Gør at hele din kode bliver evalueret så du ikke bruger tal hvor der skal stå bogstaver
Option Explicit

'GetAsyncKeyState(KNAP), giver dig en knaps status på tasteturet, fx vbKeyF11 eller vbKeyA
Private Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer

'GetTickCount(), giver dig computerens oppetid i millisekunder
Private Declare Function GetTickCount Lib "Kernel32" () As Long

'3 variabler der er tilgængelig i hele formens kode (havde jeg skrevet public (istedet for private) ville den være tilgængelig i hele programmets kode)
'Const betyder at den ikke kan ændres undervejs (konstant)
Private Const FileAdr = "Tid.txt"
Private StartTime As Long
Private BufferTime As Long

'En "sub" jeg får frem ved at dobbeltklikke på formen.
Private Sub Form_Load()
    'En variabel af samme type som GetTickCount (Long)
    Dim BufferStr As String
    
    'En variabel der kan have 2 værdier, True eller False
    Dim ShowTime As Boolean
    
    'Dir() tjekker om filen findes
    If Dir(FileAdr) <> "" Then
        Open FileAdr For Input As #1
        Line Input #1, BufferStr
        Close #1
        StartTime = GetTickCount() - CDbl(BufferStr)
        BufferTime = GetTickCount()
    Else
        StartTime = 0
        BufferTime = 0
    End If
    
    ShowTime = False
    
    'Et objekt af typen Label, der ligger på formen, skal have sin caption værdi ændret til tiden.
    'En labels caption og en textboxs text, er den tekst der bliver vist til brugeren
    'Format er en indbygget funktion i VB der gør at man kan omskrive udtryk forholdsvis enkelt
    lblTime.Caption = Format((GetTickCount() - StartTime) / 1000 / 60 / 60 / 24, "hh:mm:ss")
    
    'Jeg laver et loop i Form_Load() så vis formen med det samme
    Me.Show     'Me hentyder til den form, som koden blev skrevet i
    
    'En while-løkke der gentager sig indtil true = false, og det sker selvfølgelig aldrig
    While True
        
        'Doevents sørger for at andre programmer også får tid til at tænke
        DoEvents
        
        'Man spørger her om F9 knappen er klikket, False hvis den ikke er klikket
        If GetAsyncKeyState(vbKeyF9) <> False Then
            StartTime = 0
            BufferTime = 0
            ShowTime = False
            lblTime.Caption = Format(0, "hh:mm:ss")
        End If
        
        'Man spørger her om F11 knappen er klikket, False hvis den ikke er klikket
        If GetAsyncKeyState(vbKeyF11) <> False Then
            If ShowTime = False Then
                StartTime = StartTime + (GetTickCount() - BufferTime)
                ShowTime = True
                BufferTime = 0
            End If
        End If
        
        'Man spørger her om F12 knappen er klikket, False hvis den ikke er klikket
        If GetAsyncKeyState(vbKeyF12) <> False Then
            If ShowTime = True Then
                ShowTime = False
                BufferTime = GetTickCount()
            End If
        End If
        
        'Man spørger her om ShowTime har værdien True
        If ShowTime = True Then
            lblTime.Caption = Format((GetTickCount() - StartTime) / 1000 / 60 / 60 / 24, "hh:mm:ss")
        End If
    
    'Gå til der hvor der står while
    Wend
End Sub

'Denne "sub" fik jeg frem ved at vælge "Form" i den venstre liste, og "Unload" i den højre
Private Sub Form_Unload(Cancel As Integer)
    'Gem oplysningerne
    Open FileAdr For Output As #2
    Print #2, CStr(GetTickCount() - StartTime - IIf(BufferTime = 0, 0, (GetTickCount() - BufferTime)))
    Close #2

    'Forsøg at slette så meget som muligt fra hukommelsen
    Unload Me
    DoEvents

    'Ulempen ved at lave et loop der kører fra starten af programmets udførelse er at det ikke kan lukke da det aldrig rigtig blev sat i gang! Derfor lukker man med End.
    End
End Sub

// Your brain is your weapon, do not waste it!!

Hej er der nogle der vil hjælpe mig med at lave at spotur jeg kender ikke programmet så godt men har prøvet det lidt.

Egenskaber for storur
Det skal kunne starte når man klikker fx. "F12"

og stoppe når man fx klikker "F11"

når man har brugt den en dag og man har haft den tændt i fx 3 timer, så nær man tænder den næste dag at den foresætter fra 3 timer

og så en knap eller andet sted hvor man genstarter den

PLZ hjælp mig

hmm... burde meget nemt kunne laves... uploader lige et hurtigt eksempel om lidt...

Det var total godt lige hvad jeg havde tænkt, men der mangler en lille ting som jeg glemte at sige så vil du være sød at lave den

det er at den viser i timer, min og sek

Det var total godt lige hvad jeg havde tænkt, men der mangler en lille ting som jeg glemte at sige så vil du være sød at lave den

det er at den viser i timer, min og sek

undskyld den lange svartid... havde ikke lgie set du havde svaret tilbage...

men det eneste du skal gøre er følgende:
istedet for:
Label1.Caption = sekunder
så skal du skrive
Label1.Caption = format(sekunder / 24 / 60 / 60, "hh:mm:ss")
så omregne VB det til timer minutter og sekunder

Det var godt nok dejligt, men jeg har lige opdaget en ting mere som jeg havde glemt at sige

hvis jeg er i et andet program så skal den også tænde/slukke hvis jeg trykker på en af knapperne

håber at du vil hjælpe med at lave det

Det var godt nok dejligt, men jeg har lige opdaget en ting mere som jeg havde glemt at sige

hvis jeg er i et andet program så skal den også tænde/slukke hvis jeg trykker på en af knapperne

håber at du vil hjælpe med at lave det

hmmm forstp ikke helt dit spørgsmål, men det eg har lavet er grundkoden, som nemt burde kunne sætets ind ed hvilken som helst funktion

Jeg er lidt for doven i dag til at sætte det sammen, men til det skal du bruge API kald. GetAsyncKeyState(vbKeyF11) returnere true hvis F11 er klikket, GetAsyncKeyState(vbKeyF12) hvis du vil tjekke F12 knappen.

I toppen af din form skal du skrive:

Private Declare Function GetAsyncKeyState Lib "user32" (ByVal vKey As Long) As Integer

Og så skal du bare opstille et loop eller en timer der konstant chekker GetAsyncKeyState() statusen for de to knapper. Hvis de er klikket skal den bare udføre samme kode som den ville gøre i Cristians program, når man klikkede på knapperne. Husk en DoEvents hvis du vælger et loop.

Og så skal du vide at en timer ikke er særlig præcis til at måle tid med - især ikke hvis du har tænkt dig at den skal køre i baggrunden, mens du bruger CPU'en til noget andet. Derfor forslår jeg at du bruger GetTickCount() til at få fat i den tid som computeren har været tændt. Når man starter uret skal du så bare huske hvor lang tid computeren havde været tændt da stopuret blev startet. GetTickCount() angiver tiden i millisekunder.

For at aktivere GetTickCount() skal du i toppen af din form skrive:

Private Declare Function GetTickCount Lib "Kernel32" () As Long

// Your brain is your weapon, do not waste it!!

jeg er meget ny til programmet og forstår ikke hvad du mener kan du lave et eksempel??

tak begge to nu har jeg fundet ud af hvad jeg ville og pointene er givet