-----------------------------------------------------------------------------
Det jeg skal bruge er et unikt nummer til hver filnavn, derfor tænkte jeg at et array måske kunne bruges.
Hvis nogen har et andet forslag skal de være velkomne til at poste der her.
Mvh. Steffen Nielsen
-----------------------------------------------------------------------------
Hej Steffen
Der er altid mere end en metode (næsten altid). Jeg har skrevet et lille program til dig. Lav en form og smid en kommandoknap på formen. Smid så koden nedenfor ind. Det hele er dokumenteret med kommentarer, så det skulle være til at forstå.
Der er en rutine ved navn
HentAlleFiler. Den henter alle filer fra den angivne mappe og returnerer et array. Se
Command1_Click rutinen for oplysninger om, hvordan rutinen bruges.
Jeg bruger kun VB kode ... ikke noget API og ikke noget med
FileSystemObject eller andet hokus-pokus. Jeg tror ikke, det kan gøres meget simplere.
Håber du kan bruge det.
Herluf
<pre>
Option Explicit
Private Sub Command1_Click()
'
' Deklarer et dynamisk array til brug med
' HentAlleFiler rutinen.
'
Dim arrFiler() As String
'
' Kald rutinen uden en mappe (Windows
' mappen er default).
'
HentAlleFiler arrFiler()
'
' Udskriv lige filerne til Immediate-
' vinduet, så vi kan se, at det rent
' faktisk virker.
'
Dim lngLimit As Long
Dim lngIndex As Long
Let lngLimit = UBound(arrFiler())
For lngIndex = 1 To lngLimit
Debug.Print "Fil nr. " & lngIndex & _
" hedder '" & arrFiler(lngIndex) & _
"'"
Next
'
' Vi prøver at søge på diskens rod.
'
HentAlleFiler arrFiler(), "c:\\"
'
' Udskriv lige filerne igen.
'
Let lngLimit = UBound(arrFiler())
For lngIndex = 1 To lngLimit
Debug.Print "Fil nr. " & lngIndex & _
" hedder '" & arrFiler(lngIndex) & _
"'"
Next
End Sub
'
' Henter alle filer fra "C:\\Windows" (eller
' den mappe, du angiver) og smider dem ind i
' det array, der sendes til rutinen (dvs.
' argArray() argumentet).
'
Public Sub HentAlleFiler( _
ByRef argArray() As String, _
Optional ByVal argSearchMask As String = "c:\\windows" _
)
'
' Vi skal lige have nogle lokale
' variabler.
'
Dim curFile As String ' den fundne fil
Dim strMask As String ' søgemaske
Dim lngLimit As Long ' grænse på array
'
' Opbyg søgemasken, så den ser ud som
' f.eks. "C:\\Windows\\*.*", når vi
' begynder søgningen.
'
Let strMask = Trim$(argSearchMask)
If Right$(strMask, 1) <> "\\" Then _
Let strMask = strMask & "\\"
Let strMask = strMask & "*.*"
'
' Vi sætter den øvre grænse på array'et
' og søger på den første fil. Vi angiver
' søgemaske og de attributter, vi ønsker
' at finde. I vores tilfælde vil vi have
' alle filer men ikke mapper.
'
Let lngLimit = 0
Let curFile = Dir$(strMask, _
vbSystem Or _
vbArchive Or _
vbHidden Or _
vbReadOnly)
'
' Vi bliver nødt til at redimensionere
' array'et, før det kan bruges. Vi bruger
' IKKE Preserve her, for vi vil gerne
' slette eventuelle data fra tidligere
' kald.
'
ReDim argArray(0 To 0)
'
' Nu kører bussen simpelthen, indtil der
' ikke er flere filer i mappen. Når der
' ikke er flere filer, returnerer DIR-
' kommandoen nemlig "" (en tom streng).
'
Do While curFile <> ""
'
' REDIM PRESERVE øger størrelsen på
' det dynamiske array uden at slette
' eksisterende data.
'
ReDim Preserve argArray(0 To lngLimit)
'
' Sæt det aktuelle element til den
' fil, der blev fundet. Array'et
' starter med index 0.
'
Let argArray(lngLimit) = curFile
'
' Siden øger vi indekset og leder
' efter næste filnavn. Når næste fil
' skal findes, angives ingen parametre
' i kaldet til DIR funktionen.
'
Let lngLimit = lngLimit + 1
Let curFile = Dir$()
Loop
End Sub
</pre>
Software is here and now but rock and roll is forever.
[Redigeret d. 01/04-04 07:55:14 af Herluf Hermansen]