Nedtælling

Mange tak for din hjælp Michael.

Jeg vil lige beskrive præcis hvad jeg mener.

Hvis du nu forestiller dig at f.eks om 14 dage kl. 16:30 skal mit program stoppe og vise min Ontimer event. I dette tilfælde ’Tiden er nået’. Det vil sige at min label1 skal vise hvor mange dage,timer,min og sek der er tilbage til datoen om 14 dage og tælle ned realtime.

Håber du kan hjælpe mig videre

Mvh

Martin

Hej,

Okay her er en funktion som kan give dig år, måneder, dage, timer, minutter og sekunder mellem tiden nu og en du angiver:

(***************************************************
  Hvis du sætter en af params til -1 så bliver den ikke talt med
***************************************************)
function DateTimeReached( var AYears    : Integer;
                          var AMonths   : Integer;
                          var ADays     : Integer;
                          var AHours    : Integer;
                          var AMinutes  : Integer;
                          var ASeconds  : Integer;
                          ADateToReach  : TDateTime) : Boolean;
var
  Tmp, N : TDateTime;
begin
  Result := (CompareDateTime(ADateToReach, Now) < 0);
  if (Result) then
  begin
    if AYears <> -1 then
      AYears := 0;
    if AMonths <> -1 then
      AMonths := 0;
    if ADays <> -1 then
      ADays := 0;
    if AHours <> -1 then
      AHours := 0;
    if AMinutes <> -1 then
      AMinutes := 0;
    if ASeconds <> -1 then
      ASeconds := 0;
  end
  else
  begin
    Tmp := ADateToReach;
    N := Now;
    if AYears <> -1 then
    begin
      AYears := YearsBetween(Tmp, N);
      Tmp := IncYear(Tmp,-AYears);
    end;
    if AMonths <> -1 then
    begin
      AMonths := MonthsBetween(Tmp, N);
      Tmp := IncMonth(Tmp,-AMonths);
    end;
    if ADays <> -1 then
    begin
      ADays := DaysBetween(Tmp, N);
      Tmp := IncDay(Tmp,-ADays);
    end;
    if AHours <> -1 then
    begin
      AHours := HoursBetween(Tmp, N);
      Tmp := IncHour(Tmp,-AHours);
    end;
    if AMinutes <> -1 then
    begin
      AMinutes := MinutesBetween(Tmp, N);
      Tmp := IncMinute(Tmp,-AMinutes);
    end;
    if ASeconds <> -1 then
    begin
      ASeconds := SecondsBetween(Tmp, N);
    end;
  end;
end;

F.eks. så kunne dit timer event se således ud:

procedure TForm1.Timer1Timer(Sender: TObject);
  function addValue(Value : Integer; Suffix : String) : String;
  begin
    Result := IntToStr(Value)+Suffix;
  end;
var
  Y, M, D, H, N, S : Integer;
begin
  Y := 0;
  M := 0;
  D := 0;
  H := 0;
  N := 0;
  S := 0;
  if DateTimeReached(Y, M, D, H, N, S, FSlutDato) then
    Label1.Caption := 'WHHEEEEE! IT''S TIME!!!'
  else
    Label1.Caption := AddValue(Y, ' år ')+
                      AddValue(M, ' måneder ')+
                      AddValue(D, ' dage ')+
                      AddValue(H, ' timer ')+
                      AddValue(N, ' minutter ')+
                      AddValue(S, ' sekunder ');
end;

Hvis du nu kun vil ha' dage, timer minutter og sekunder så sæt Y og M til -1 :

procedure TForm1.Timer1Timer(Sender: TObject);
  function addValue(Value : Integer; Suffix : String) : String;
  begin
    Result := IntToStr(Value)+Suffix;
  end;
var
  Y, M, D, H, N, S : Integer;
begin
  Y := 0;
  M := 0;
  D := 0;
  H := 0;
  N := 0;
  S := 0;
  if DateTimeReached(Y, M, D, H, N, S, FSlutDato) then
    Label1.Caption := 'WHHEEEEE! IT''S TIME!!!'
  else
    Label1.Caption := AddValue(D, ' dage ')+
                      AddValue(H, ' timer ')+
                      AddValue(N, ' minutter ')+
                      AddValue(S, ' sekunder ');
end;

Håber det hjælper dig.
Hvis du skal gennem den dato/tid som programmet skal vente på, så brug evt. registry til at gemme denne variable.

Mvh
Michael.

Hej udviklere

Jeg skal lave et program som kan tælle ned til en bestemt dato på et bestemt tidspunkt og man skal kunne se tiden og datoen tælle ned. Det skal altså kunne afsluttes og når det startes igen skal det opdatere tiden og datoen fra f.eks Windows og tælle ned derfra igen.
Jeg er selv rimelig blank så jeg håber nogen kan hjælpe mig.

Mvh

Martin

Hej Martin,

Jeg er ikke helt sikker på hvad du mener men here goes:
1. En dato tæller man frem eller tilbage men når du skriver "ned" mener du så tilbage?
2. Hvor hurtig vil du ha' tiden til at tælle (realtime eller?)?

En dato-tid værdi gemmes i en TDateTime. Hvis du skal bruge tiden "lige nu" så kan du bruge funktionen "Now" som returnere en TDateTime. For at lave en TDateTime om til en streng skal/kan du bruge funktionen "DateTimeToStr".

Det var så lidt om hvordan du kan manipulere tiden i en variable.
Her er et lille kode stykke som tæller startup-tiden tilbage til dagen før.

Først skal du oprette en form og placere en TLabel og en TTimer komponent på denne.

1. Tilføj DateUtils til uses.

2. Opret to private variabler af typen TDateTime (findes i SysUtils).

  private
    FDato : TDateTime;
    FSlutDato : TDateTime;

3. Vælg formen og opret eventet "OnCreate". Indsæt følgende kode i eventet:

procedure TForm1.FormCreate(Sender: TObject);
begin
  FDato := Now; // Hent den aktuelle dato-tid.
  FSlutDato := IncDay(FDato, -1); // sæt Slut datoen til dagen før.
end;

4. Vælg TTimer komponenten og opret eventet "OnTimer" (Object inspector->Events, dobbelt klik på "OnTimer"). Nu skal du indsætte følgende kode:

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  if CompareDateTime(FSlutDato, FDato) < 0 then // Sammenlign vores to datoer
  begin  // Okay, slut datoen er ikke nået endnu.
    FDato := IncSecond(FDato, -3600); // tæl datoen 1 time tilbage.
    Label1.Caption := DateTimeToStr(FDato); // Konverter datoen til en streng og vis den i label1.
  end
  else // Whheee, endelig har vi nået målet.
    Label1.Caption := 'Datoen er nået!';
end;

Din kode skulle gerne se således ud:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls, DateUtils;

type
  TForm1 = class(TForm)
    Label1: TLabel;
    Timer1: TTimer;
    procedure Timer1Timer(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    FDato : TDateTime;
    FSlutDato : TDateTime;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  if CompareDateTime(FSlutDato, FDato) < 0 then // Sammenlign vores to datoer
  begin  // Okay, slut datoen er ikke nået endnu.
    FDato := IncSecond(FDato, -1); // tæl datoen 1 sekund tilbage.
    Label1.Caption := DateTimeToStr(FDato); // Konverter datoen til en streng og vis den i label1.
  end
  else // Whheee, endelig har vi nået målet.
    Label1.Caption := 'Datoen er nået!';
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FDato := Now; // Hent den aktuelle dato-tid.
  FSlutDato := IncDay(FDato, -1); // sæt Slut datoen til dagen før.
end;

end.

Dette skulle gerne give dig lidt at starte på (håber jeg) så god fornøjelse.

Michael.

Mange tak for din hjælp Michael.

Jeg vil lige beskrive præcis hvad jeg mener.

Hvis du nu forestiller dig at f.eks om 14 dage kl. 16:30 skal mit program stoppe og vise min Ontimer event. I dette tilfælde ’Tiden er nået’. Det vil sige at min label1 skal vise hvor mange dage,timer,min og sek der er tilbage til datoen om 14 dage og tælle ned realtime.

Håber du kan hjælpe mig videre

Mvh

Martin

Det ser alt sammen meget fint ud, men hvordan indstiller jeg tiden og datoen for den dato der skal tælles ned til. Jeg ved heller ikke hvordan man gemmer i registry.

Endnu en gang tak for hjælpen

Mvh

Martin

Det ser alt sammen meget fint ud, men hvordan indstiller jeg tiden og datoen for den dato der skal tælles ned til. Jeg ved heller ikke hvordan man gemmer i registry.

Endnu en gang tak for hjælpen

Mvh

Martin

For at lave en dato kan du bruge følgende funktion:

  FSlutDato := EncodeDateTime(y,m,d,h,n,s,ms);
  // y=år, m=måned, d=dag, h=time, n=minut, s=sekund, ms=millisekund

for at bruge registry skal du benytte klassen TRegistry som ligger i registry (skal indsætte under uses).

procedure SaveDateTime(AValue : TDateTime);
var
  R : TRegistry;
begin
  R := TRegistry.Create;
  try
    R.RootKey := HKEY_LOCAL_MACHINE;
    if R.OpenKey('Software\\Dit program navn', True) then
    begin
      R.WriteDateTime('SlutTid', AValue);
    end;
  finally
    R.Free;
  end;
end;

function LoadDateTime : TDateTime;
var
  R : TRegistry;
begin
  R := TRegistry.Create;
  try
    R.RootKey := HKEY_LOCAL_MACHINE;
    if R.OpenKey('Software\\Dit program navn', False) then
    begin
      Result := R.ReadDateTime('SlutTid');
    end
    else
      Result := Now;
  finally
    R.Free;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  FSlutDato := LoadDateTime;
end;

// Denne funktion skal tilføjes på samme måde som "FromCreate".
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  SaveDateTime(FSlutDato);
end;

Michael.

Der er mange fine løsninger, men det I glemmer er at lade Delphi gøre arbejdet for jer. Jeg vil ikke gennemgå registry osv. men her er en løsning på nedtællingen som er meget meget nem.

Du skal have en variabel af typen TDateTime. Denne variabel kan gemmes i registreringsdatabasen eller en ini-fil, eller hvad du nu vil.
Derudover skal du have en TTimer og en TLabel.
I TTimerens OnTimer hændelse skriver du simpelthen følgende:

  Label1.Caption := FormatDateTime(
     'Y "år", M "måneder", D "dage", H "timer", N "minutter og" S "sekunder tilbage"', 
    FSlut - now);

Dermed får du en nem nedtælling som er nøjagtig inden et sekund.

---
Thomas Due
tdue@mail.dk

Der er mange fine løsninger, men det I glemmer er at lade Delphi gøre arbejdet for jer. Jeg vil ikke gennemgå registry osv. men her er en løsning på nedtællingen som er meget meget nem.

Du skal have en variabel af typen TDateTime. Denne variabel kan gemmes i registreringsdatabasen eller en ini-fil, eller hvad du nu vil. Denne variabel kalder vi FSlut. Den skal f.eks. erklæres i private delen af din form erklæring. Derudover skal du have en TTimer og en TLabel.

I TTimerens OnTimer hændelse skriver du simpelthen følgende:

  Label1.Caption := FormatDateTime(
     'Y "år", M "måneder", D "dage", H "timer", N "minutter og" S "sekunder tilbage"', 
    FSlut - now);

Dermed får du en nem nedtælling som er nøjagtig inden et sekund.

---
Thomas Due
tdue@mail.dk[Redigeret d. 20/03-03 14:17:35 af Thomas Due]

Der er mange fine løsninger, men det I glemmer er at lade Delphi gøre arbejdet for jer. Jeg vil ikke gennemgå registry osv. men her er en løsning på nedtællingen som er meget meget nem.

Du skal have en variabel af typen TDateTime. Denne variabel kan gemmes i registreringsdatabasen eller en ini-fil, eller hvad du nu vil. Denne variabel kalder vi FSlut. Den skal f.eks. erklæres i private delen af din form erklæring. Derudover skal du have en TTimer og en TLabel.

I TTimerens OnTimer hændelse skriver du simpelthen følgende:

Kode 

  Label1.Caption := FormatDateTime(
     'Y "år", M "måneder", D "dage", H "timer", N "minutter og" S "sekunder tilbage"', 
    FSlut - now);

Dermed får du en nem nedtælling som er nøjagtig inden et sekund.

---
Thomas Due
tdue@mail.dk[Redigeret d. 20/03-03 14:17:35 af Thomas Due]

Den holder ikke helt!
Når der er mindre end et år tilbage så får du f.eks. :
"99 år, 12 måneder, 30 dage, 0 timer, 0 minutter og 59 sekunder tilbage".

En anden ting, hvis der er 1 time og 30 minutter tilbage og du vælger kun at se hvor mange minutter der er tilbage så giver den ovenstående 30 minutter hvor min giver dig 90 minutter.

Dernæst her jeg lige en lille ændring til indlæsning af data fra registry:

function LoadDateTime : TDateTime;
var
  R : TRegistry;
begin
  Result := Now;
  R := TRegistry.Create;
  try
    R.RootKey := HKEY_LOCAL_MACHINE;
    if R.OpenKey('Software\\Dit program navn', False) then
      if (R.ValueExists('SlutTid')) then
        Result := R.ReadDateTime('SlutTid');
  finally
    R.Free;
  end;
end;

Michael.
[Redigeret d. 20/03-03 18:34:19 af Michael Skovslund]