Tags:    delphi
Nu er vi klar til at implementere vores lyskilde. Jeg nævnte før at der var 8 lyskilder tilgænglige. Den første hedder Ligtht0 og den sidste hedder Light7. Af naturlig logisk sans vælger vi Light0 og gør den tilgængelig med OpenGL funktionen glEnable(). Alle lyskilder i OpenGL har tre farve shaders (Ambient, Diffuse og Specular). Funktionen glLightfv() bruger vi til at angive farverne (gl_Ambient, gl_Diffuse, gl_Specular). Ambient er farven der skygger vores geometri, diffuse er farven der oplyser vores geomteri og specular er farven der over-oplyser (highlighter) vores geometri. Alle farverne skal defineres som Red, Green og Blue, hvor af alle skal være singles. Vi vil derfor lave en record med disse informationer:

type
  TLysFarve = record
    Red, Green, Blue : Single;
  end;

Udover det skal vores lys havde en position. Til det burde vi kunne benytte en TVector, men da der i nogen tilfælde, skal tages hensyn til en lys bredde (Width) bliver vi nødt til at definere en ny record (X,Y,Z,W). I vores eksempeler sætter vi altid vores W til 1!

  TLysPosition = record
    X, Y, Z, W : Single;
    end;

Da OpenGL ikke som default er sat op til at shade geometri, skal vi fortælle at vores lyskilde skal shade vores geometris farver, også selv om vi kun bruger textures, med glEnable(gl_Color_Material).

var
  Translation, Rotation : TVector;
  LysAmbient : TLysFarve = (Red : 0.25; Green : 0.25; Blue : 0.25);
  LysDiffuse : TLysFarve = (Red : 1; Green : 1; Blue : 1);
  LysSpecular : TLysFarve = (Red : 0.5; Green : 0.5; Blue : 0.5);
  LysPosition : TLysPosition = (X : -11; Y : 10; Z : -40; W: 1);
procedure TForm1.FormPaint(Sender: TObject);
begin
  glClearColor(0,0,0,0);

  glClear(gl_Color_Buffer_Bit or gl_Depth_Buffer_Bit);

  glEnable(gl_Depth_Test);

  glEnable(gl_Normalize);

  glEnable(gl_Color_Material);

  glPushMatrix;

  with Rotation do
  begin
    glRotatef(X,1,0,0);
    glRotatef(Y,0,1,0);
    glRotatef(Z,0,0,1);
  end;

  with Translation do
  glTranslatef(X,Y,Z);


  //Skaber vores lyskilde
  glEnable(gl_Light0);
  
  //Definere ambient, diffuse og specular farverene for vores lyskilde
  glLightfv(gl_Light0, gl_Ambient, @LysAmbient);
  glLightfv(gl_Light0, gl_Diffuse, @LysDiffuse);
  glLightfv(gl_Light0, gl_Specular, @LysSpecular);
  glLightfv(gl_Light0, gl_Position, @LysPosition);

  //Disabler lysshading og textures inden vi tegner vores lyskilde
  glDisable(gl_Lighting);
  glDisable(gl_Texture_2D);

  //Tegner vores lyskilde som en hvid punkt
  glPointSize(4);
  glBegin(gl_Points);
    glVertex3fv(@LysPosition);
  glEnd;
  
  //Gøre vore lysshading og textures tilgængelig igen
  glEnable(gl_Ligting);
  glEnable(gl_Texture_2D);

  //Aktivere mit gulv texture
  glBindTexture(gl_Texture_2D, Gulv_ID);

  //Tegner mit gulv
  glBegin(gl_Quads);

  //Definere en normal for gulvet, der peger lodret op ad!
  glNormal3f(0, 1, 0);

  glTexCoord2f(0,4);
  glVertex3f(-50, -3, -50);
  glTexCoord2f(0,0);
  glVertex3f(-50, -3, +50);
  glTexCoord2f(4,0);
  glVertex3f(+50, -3, +50);
  glTexCoord2f(4,4);
  glVertex3f(+50 ,-3 ,-50);
  glEnd;

  //Aktivere mit væg texture
  glBindTexture(gl_Texture_2D, Vaeg_ID);

  //Tegner min væg
  glBegin(gl_Quads);

  //DFefinere en normal for væggen, der peger imod os (ud fra væggen) 
  glNormal3f(0, 0, 1);

  glTexCoord2f(0,1);
  glVertex3f(-50, -3, -50);
  glTexCoord2f(0,0);
  glVertex3f(-50, +22, -50);
  glTexCoord2f(4,0);
  glVertex3f(+50, +22, -50);
  glTexCoord2f(4,1);
  glVertex3f(+50, -3, -50);
  glEnd;

  //Aktivere mit loft texture
  glBindTexture(gl_Texture_2D, Loft_ID);

  //Tegner mit loft
  glBegin(gl_Quads);

  //Definere en normal for loftet, der peger ned mod gulvet
  glNormal3f(0,-1, 0);

  glTexCoord2f(0,4);
  glVertex3f(-50, +22, -50);
  glTexCoord2f(0,0);
  glVertex3f(-50, +22, +50);
  glTexCoord2f(4,0);
  glVertex3f(+50, +22, +50);
  glTexCoord2f(4,4);
  glVertex3f(+50 ,+22 ,-50);
  glEnd;

  glPopMatrix;


  SwapBuffers(Context.DeviceContext);
end;

Som du kan se har vi yderligere tegnet vores lyskilde som en hvid punkt. Dette er selvfølgelig ikke nødvendigt, men det er altid meget rart at kunne se præcist, hvor vores lyskilde befinder sig. For at opnå en korrekt shading bliver vi nødt til at ændre vores matrix's form for at beregne, to gange, i vores FormResize procedure. Inden vi resetter vores matrix med glLoadIdentity skal vi gøre OpenGL opmærksom på at vores matrix skal projekteres med glMatrixMode(gl_Projection). Til sidst skal OpenGL være klar til at beregne geometri forholde med glMatrixMode(gl_ModelView). Hvorfor så det? Når vi ændre på vores viewport eller frustum, ændre vi også på den måde vores geometri bliver projekteret på. Dette har hidtil ikke været vigtig at informere OpenGL om, da vi ikke har haft nogen lysprojekteringer før. Efter vi har ændret på vores viewport og frustum, er det vigtig at fortælle OpenGL, at der kun skal beregnes med geometri forholde ellers kan vi ikke være sikre på at vores normals bliver beregnet korrekt.

procedure TForm1.FormResize(Sender: TObject);
begin
  //Sikre os at lyskilden blier beregnet korrekt
  glMatrixMode(gl_Projection);

  glLoadIdentity;
  glViewport(0, 0, ClientWidth, ClientHeight);
  glFrustum(-1.0, +1.0, -(ClientHeight/ClientWidth), ClientHeight/ClientWidth, 2, 500);

  //Beregner vores normals korrekt i forhold til lyset
  glMatrixMode(gl_ModelView);
end;

Shaded (Ikke textured)


Shaded (Textured)

Prøver vi at kompile, vil du svagt kunne bemærke at geometrien er blevet shadet. Det er ikke så tydeligt da lyskilden oplyser alt vores geometri næsten lige meget. For at se det tydligere har jeg valt at erstatte vores loft med en Kasse.

procedure TForm1.FormPaint(Sender: TObject);
begin
  glClearColor(0,0,0,0);
  glClear(gl_Color_Buffer_Bit or gl_Depth_Buffer_Bit);

  glEnable(gl_Depth_Test);

  glEnable(gl_Normalize);

  glEnable(gl_Color_Material);

  glPushMatrix;

  with Rotation do
  begin
    glRotatef(X,1,0,0);
    glRotatef(Y,0,1,0);
    glRotatef(Z,0,0,1);
  end;

  with Translation do
  glTranslatef(X,Y-5,Z);

  glLightfv(gl_Light0, gl_Ambient, @LysAmbient);
  glLightfv(gl_Light0, gl_Diffuse, @LysDiffuse);
  glLightfv(gl_Light0, gl_Specular, @LysSpecular);
  glLightfv(gl_Light0, gl_Position, @LysPosition);
  glEnable(gl_Light0);

  glDisable(gl_Lighting);
  glDisable(gl_Texture_2D);

  glPointSize(4);
  glBegin(gl_Points);
    glVertex3fv(@LysPosition);
  glEnd;

  glEnable(gl_Lighting);
  glEnable(gl_Texture_2D);

  //Aktivere mit gulv texture
  glBindTexture(gl_Texture_2D, Gulv_ID);

  //Tegner mit gulv
  glBegin(gl_Quads);
    //Normal for gulvet (Peger lodret op!)
    glNormal3f(0, 1, 0);
    glTexCoord2f(0,4);
    glVertex3f(-50, -3, -50);
    glTexCoord2f(0,0);
    glVertex3f(-50, -3, +50);
    glTexCoord2f(4,0);
    glVertex3f(+50, -3, +50);
    glTexCoord2f(4,4);
    glVertex3f(+50, -3, -50);
  glEnd;

  //Aktivere mit væg texture
  glBindTexture(gl_Texture_2D, Vaeg_ID);

  //Tegner min væg
  glBegin(gl_Quads);
    glNormal3f(0,0,1);
    glTexCoord2f(0,1);
    glVertex3f(-50, -3, -50);
    glTexCoord2f(0,0);
    glVertex3f(-50, +22, -50);
    glTexCoord2f(4,0);
    glVertex3f(+50, +22, -50);
    glTexCoord2f(4,1);
    glVertex3f(+50, -3, -50);
  glEnd;

  //Aktivere kassens texture med Loft_ID
  glBindTexture(gl_Texture_2D, Loft_ID);

  //Begynder på kassens matrix
  glPushMatrix;
    
    //Flytter kassen til en mere passende sted!
    glTranslatef(-10, 0, 5);

    //Definere vores kasse
    glBegin(gl_Quads);

      // 1) normal. (Peger mod dig!)
      glNormal3f( 0, 0, 1);
      //Koordinater for første side (Forside)
      glTexCoord2f(0, 0); glVertex3f(-3, -3,  3);
      glTexCoord2f(1, 0); glVertex3f( 3, -3,  3);
      glTexCoord2f(1, 1); glVertex3f( 3,  3,  3);
      glTexCoord2f(0, 1); glVertex3f(-3,  3,  3);

      // 3) normal (Peger væk fra dig!)
      glNormal3f( 0, 0,-1);
      //Koordinater for anden side (Bagsiden)
      glTexCoord2f(1, 0); glVertex3f(-3, -3, -3);
      glTexCoord2f(1, 1); glVertex3f(-3,  3, -3);
      glTexCoord2f(0, 1); glVertex3f( 3,  3, -3);
      glTexCoord2f(0, 0); glVertex3f( 3, -3, -3);

      // 3) normal
      glNormal3f( 0, 1, 0);
      //Koordinater for tredje siden (Toppen)
      glTexCoord2f(0, 1); glVertex3f(-3,  3, -3);
      glTexCoord2f(0, 0); glVertex3f(-3,  3,  3);
      glTexCoord2f(1, 0); glVertex3f( 3,  3,  3);
      glTexCoord2f(1, 1); glVertex3f( 3,  3, -3);

      // 4) normal
      glNormal3f( 0,-1, 0);
      //Koordinater for fjerde side (Bunden)
      glTexCoord2f(1, 1); glVertex3f(-3, -3, -3);
      glTexCoord2f(0, 1); glVertex3f( 3, -3, -3);
      glTexCoord2f(0, 0); glVertex3f( 3, -3,  3);
      glTexCoord2f(1, 0); glVertex3f(-3, -3,  3);

      // 5) normal
      glNormal3f( 1, 0, 0);
      //Koordinater for femte side (Højre)
      glTexCoord2f(1, 0); glVertex3f( 3, -3, -3);
      glTexCoord2f(1, 1); glVertex3f( 3,  3, -3);
      glTexCoord2f(0, 1); glVertex3f( 3,  3,  3);
      glTexCoord2f(0, 0); glVertex3f( 3, -3,  3);

      // 6) normal
      glNormal3f(-1, 0, 0);
      //Koordinater for sjette side (Venstre)
      glTexCoord2f(0, 0); glVertex3f(-3, -3, -3);
      glTexCoord2f(1, 0); glVertex3f(-3, -3,  3);
      glTexCoord2f(1, 1); glVertex3f(-3,  3,  3);
      glTexCoord2f(0, 1); glVertex3f(-3,  3, -3);
    glEnd;

  //Afslutter kassens matrix
  glPopMatrix;

  glPopMatrix;

  SwapBuffers(Context.DeviceContext);
end;

Hvad synes du om denne artikel? Giv din mening til kende ved at stemme via pilene til venstre og/eller lægge en kommentar herunder.

Del også gerne artiklen med dine Facebook venner:  

Karma barometer (30 dage)

IT jobs | Kontakt | Om Udvikleren.dk | Om karma | IT nyheds arkiv | Annoncering

X